home *** CD-ROM | disk | FTP | other *** search
/ SGI Developer Toolbox 6.1 / SGI Developer Toolbox 6.1 - Disc 4.iso / lib / mathlib / libblas / src_original / ctpmv.f < prev    next >
Encoding:
Text File  |  1994-08-02  |  10.9 KB  |  342 lines
  1. *
  2. ************************************************************************
  3. *
  4.       SUBROUTINE CTPMV ( UPLO, TRANS, DIAG, N, AP, X, INCX )
  5. *     .. Scalar Arguments ..
  6.       INTEGER            INCX, N
  7.       CHARACTER*1        DIAG, TRANS, UPLO
  8. *     .. Array Arguments ..
  9.       COMPLEX            AP( * ), X( * )
  10. *     ..
  11. *
  12. *  Purpose
  13. *  =======
  14. *
  15. *  CTPMV  performs one of the matrix-vector operations
  16. *
  17. *     x := A*x,   or   x := A'*x,   or   x := conjg( A' )*x,
  18. *
  19. *  where x is an n element vector and  A is an n by n unit, or non-unit,
  20. *  upper or lower triangular matrix, supplied in packed form.
  21. *
  22. *  Parameters
  23. *  ==========
  24. *
  25. *  UPLO   - CHARACTER*1.
  26. *           On entry, UPLO specifies whether the matrix is an upper or
  27. *           lower triangular matrix as follows:
  28. *
  29. *              UPLO = 'U' or 'u'   A is an upper triangular matrix.
  30. *
  31. *              UPLO = 'L' or 'l'   A is a lower triangular matrix.
  32. *
  33. *           Unchanged on exit.
  34. *
  35. *  TRANS  - CHARACTER*1.
  36. *           On entry, TRANS specifies the operation to be performed as
  37. *           follows:
  38. *
  39. *              TRANS = 'N' or 'n'   x := A*x.
  40. *
  41. *              TRANS = 'T' or 't'   x := A'*x.
  42. *
  43. *              TRANS = 'C' or 'c'   x := conjg( A' )*x.
  44. *
  45. *           Unchanged on exit.
  46. *
  47. *  DIAG   - CHARACTER*1.
  48. *           On entry, DIAG specifies whether or not A is unit
  49. *           triangular as follows:
  50. *
  51. *              DIAG = 'U' or 'u'   A is assumed to be unit triangular.
  52. *
  53. *              DIAG = 'N' or 'n'   A is not assumed to be unit
  54. *                                  triangular.
  55. *
  56. *           Unchanged on exit.
  57. *
  58. *  N      - INTEGER.
  59. *           On entry, N specifies the order of the matrix A.
  60. *           N must be at least zero.
  61. *           Unchanged on exit.
  62. *
  63. *  AP     - COMPLEX          array of DIMENSION at least
  64. *           ( ( n*( n + 1 ) )/2 ).
  65. *           Before entry with  UPLO = 'U' or 'u', the array AP must
  66. *           contain the upper triangular matrix packed sequentially,
  67. *           column by column, so that AP( 1 ) contains a( 1, 1 ),
  68. *           AP( 2 ) and AP( 3 ) contain a( 1, 2 ) and a( 2, 2 )
  69. *           respectively, and so on.
  70. *           Before entry with UPLO = 'L' or 'l', the array AP must
  71. *           contain the lower triangular matrix packed sequentially,
  72. *           column by column, so that AP( 1 ) contains a( 1, 1 ),
  73. *           AP( 2 ) and AP( 3 ) contain a( 2, 1 ) and a( 3, 1 )
  74. *           respectively, and so on.
  75. *           Note that when  DIAG = 'U' or 'u', the diagonal elements of
  76. *           A are not referenced, but are assumed to be unity.
  77. *           Unchanged on exit.
  78. *
  79. *  X      - COMPLEX          array of dimension at least
  80. *           ( 1 + ( n - 1 )*abs( INCX ) ).
  81. *           Before entry, the incremented array X must contain the n
  82. *           element vector x. On exit, X is overwritten with the
  83. *           tranformed vector x.
  84. *
  85. *  INCX   - INTEGER.
  86. *           On entry, INCX specifies the increment for the elements of
  87. *           X. INCX must not be zero.
  88. *           Unchanged on exit.
  89. *
  90. *
  91. *  Level 2 Blas routine.
  92. *
  93. *  -- Written on 22-October-1986.
  94. *     Jack Dongarra, Argonne National Lab.
  95. *     Jeremy Du Croz, Nag Central Office.
  96. *     Sven Hammarling, Nag Central Office.
  97. *     Richard Hanson, Sandia National Labs.
  98. *
  99. *
  100. *     .. Parameters ..
  101.       COMPLEX            ZERO
  102.       PARAMETER        ( ZERO = ( 0.0E+0, 0.0E+0 ) )
  103. *     .. Local Scalars ..
  104.       COMPLEX            TEMP
  105.       INTEGER            I, INFO, IX, J, JX, K, KK, KX
  106.       LOGICAL            NOCONJ, NOUNIT
  107. *     .. External Functions ..
  108.       LOGICAL            LSAME
  109.       EXTERNAL           LSAME
  110. *     .. External Subroutines ..
  111.       EXTERNAL           XERBLA
  112. *     .. Intrinsic Functions ..
  113.       INTRINSIC          CONJG
  114. *     ..
  115. *     .. Executable Statements ..
  116. *
  117. *     Test the input parameters.
  118. *
  119.       INFO = 0
  120.       IF     ( .NOT.LSAME( UPLO , 'U' ).AND.
  121.      $         .NOT.LSAME( UPLO , 'L' )      )THEN
  122.          INFO = 1
  123.       ELSE IF( .NOT.LSAME( TRANS, 'N' ).AND.
  124.      $         .NOT.LSAME( TRANS, 'T' ).AND.
  125.      $         .NOT.LSAME( TRANS, 'C' )      )THEN
  126.          INFO = 2
  127.       ELSE IF( .NOT.LSAME( DIAG , 'U' ).AND.
  128.      $         .NOT.LSAME( DIAG , 'N' )      )THEN
  129.          INFO = 3
  130.       ELSE IF( N.LT.0 )THEN
  131.          INFO = 4
  132.       ELSE IF( INCX.EQ.0 )THEN
  133.          INFO = 7
  134.       END IF
  135.       IF( INFO.NE.0 )THEN
  136.          CALL XERBLA( 'CTPMV ', INFO )
  137.          RETURN
  138.       END IF
  139. *
  140. *     Quick return if possible.
  141. *
  142.       IF( N.EQ.0 )
  143.      $   RETURN
  144. *
  145.       NOCONJ = LSAME( TRANS, 'T' )
  146.       NOUNIT = LSAME( DIAG , 'N' )
  147. *
  148. *     Set up the start point in X if the increment is not unity. This
  149. *     will be  ( N - 1 )*INCX  too small for descending loops.
  150. *
  151.       IF( INCX.LE.0 )THEN
  152.          KX = 1 - ( N - 1 )*INCX
  153.       ELSE IF( INCX.NE.1 )THEN
  154.          KX = 1
  155.       END IF
  156. *
  157. *     Start the operations. In this version the elements of AP are
  158. *     accessed sequentially with one pass through AP.
  159. *
  160.       IF( LSAME( TRANS, 'N' ) )THEN
  161. *
  162. *        Form  x:= A*x.
  163. *
  164.          IF( LSAME( UPLO, 'U' ) )THEN
  165.             KK = 1
  166.             IF( INCX.EQ.1 )THEN
  167.                DO 20, J = 1, N
  168.                   IF( X( J ).NE.ZERO )THEN
  169.                      TEMP = X( J )
  170.                      K    = KK
  171.                      DO 10, I = 1, J - 1
  172.                         X( I ) = X( I ) + TEMP*AP( K )
  173.                         K      = K      + 1
  174.    10                CONTINUE
  175.                      IF( NOUNIT )
  176.      $                  X( J ) = X( J )*AP( KK + J - 1 )
  177.                   END IF
  178.                   KK = KK + J
  179.    20          CONTINUE
  180.             ELSE
  181.                JX = KX
  182.                DO 40, J = 1, N
  183.                   IF( X( JX ).NE.ZERO )THEN
  184.                      TEMP = X( JX )
  185.                      IX   = KX
  186.                      DO 30, K = KK, KK + J - 2
  187.                         X( IX ) = X( IX ) + TEMP*AP( K )
  188.                         IX      = IX      + INCX
  189.    30                CONTINUE
  190.                      IF( NOUNIT )
  191.      $                  X( JX ) = X( JX )*AP( KK + J - 1 )
  192.                   END IF
  193.                   JX = JX + INCX
  194.                   KK = KK + J
  195.    40          CONTINUE
  196.             END IF
  197.          ELSE
  198.             KK = ( N*( N + 1 ) )/2
  199.             IF( INCX.EQ.1 )THEN
  200.                DO 60, J = N, 1, -1
  201.                   IF( X( J ).NE.ZERO )THEN
  202.                      TEMP = X( J )
  203.                      K    = KK
  204.                      DO 50, I = N, J + 1, -1
  205.                         X( I ) = X( I ) + TEMP*AP( K )
  206.                         K      = K      - 1
  207.    50                CONTINUE
  208.                      IF( NOUNIT )
  209.      $                  X( J ) = X( J )*AP( KK - N + J )
  210.                   END IF
  211.                   KK = KK - ( N - J + 1 )
  212.    60          CONTINUE
  213.             ELSE
  214.                KX = KX + ( N - 1 )*INCX
  215.                JX = KX
  216.                DO 80, J = N, 1, -1
  217.                   IF( X( JX ).NE.ZERO )THEN
  218.                      TEMP = X( JX )
  219.                      IX   = KX
  220.                      DO 70, K = KK, KK - ( N - ( J + 1 ) ), -1
  221.                         X( IX ) = X( IX ) + TEMP*AP( K )
  222.                         IX      = IX      - INCX
  223.    70                CONTINUE
  224.                      IF( NOUNIT )
  225.      $                  X( JX ) = X( JX )*AP( KK - N + J )
  226.                   END IF
  227.                   JX = JX - INCX
  228.                   KK = KK - ( N - J + 1 )
  229.    80          CONTINUE
  230.             END IF
  231.          END IF
  232.       ELSE
  233. *
  234. *        Form  x := A'*x  or  x := conjg( A' )*x.
  235. *
  236.          IF( LSAME( UPLO, 'U' ) )THEN
  237.             KK = ( N*( N + 1 ) )/2
  238.             IF( INCX.EQ.1 )THEN
  239.                DO 110, J = N, 1, -1
  240.                   TEMP = X( J )
  241.                   K    = KK     - 1
  242.                   IF( NOCONJ )THEN
  243.                      IF( NOUNIT )
  244.      $                  TEMP = TEMP*AP( KK )
  245.                      DO 90, I = J - 1, 1, -1
  246.                         TEMP = TEMP + AP( K )*X( I )
  247.                         K    = K    - 1
  248.    90                CONTINUE
  249.                   ELSE
  250.                      IF( NOUNIT )
  251.      $                  TEMP = TEMP*CONJG( AP( KK ) )
  252.                      DO 100, I = J - 1, 1, -1
  253.                         TEMP = TEMP + CONJG( AP( K ) )*X( I )
  254.                         K    = K    - 1
  255.   100                CONTINUE
  256.                   END IF
  257.                   X( J ) = TEMP
  258.                   KK     = KK   - J
  259.   110          CONTINUE
  260.             ELSE
  261.                JX = KX + ( N - 1 )*INCX
  262.                DO 140, J = N, 1, -1
  263.                   TEMP = X( JX )
  264.                   IX   = JX
  265.                   IF( NOCONJ )THEN
  266.                      IF( NOUNIT )
  267.      $                  TEMP = TEMP*AP( KK )
  268.                      DO 120, K = KK - 1, KK - J + 1, -1
  269.                         IX   = IX   - INCX
  270.                         TEMP = TEMP + AP( K )*X( IX )
  271.   120                CONTINUE
  272.                   ELSE
  273.                      IF( NOUNIT )
  274.      $                  TEMP = TEMP*CONJG( AP( KK ) )
  275.                      DO 130, K = KK - 1, KK - J + 1, -1
  276.                         IX   = IX   - INCX
  277.                         TEMP = TEMP + CONJG( AP( K ) )*X( IX )
  278.   130                CONTINUE
  279.                   END IF
  280.                   X( JX ) = TEMP
  281.                   JX      = JX   - INCX
  282.                   KK      = KK   - J
  283.   140          CONTINUE
  284.             END IF
  285.          ELSE
  286.             KK = 1
  287.             IF( INCX.EQ.1 )THEN
  288.                DO 170, J = 1, N
  289.                   TEMP = X( J )
  290.                   K    = KK     + 1
  291.                   IF( NOCONJ )THEN
  292.                      IF( NOUNIT )
  293.      $                  TEMP = TEMP*AP( KK )
  294.                      DO 150, I = J + 1, N
  295.                         TEMP = TEMP + AP( K )*X( I )
  296.                         K    = K    + 1
  297.   150                CONTINUE
  298.                   ELSE
  299.                      IF( NOUNIT )
  300.      $                  TEMP = TEMP*CONJG( AP( KK ) )
  301.                      DO 160, I = J + 1, N
  302.                         TEMP = TEMP + CONJG( AP( K ) )*X( I )
  303.                         K    = K    + 1
  304.   160                CONTINUE
  305.                   END IF
  306.                   X( J ) = TEMP
  307.                   KK     = KK   + ( N - J + 1 )
  308.   170          CONTINUE
  309.             ELSE
  310.                JX = KX
  311.                DO 200, J = 1, N
  312.                   TEMP = X( JX )
  313.                   IX   = JX
  314.                   IF( NOCONJ )THEN
  315.                      IF( NOUNIT )
  316.      $                  TEMP = TEMP*AP( KK )
  317.                      DO 180, K = KK + 1, KK + N - J
  318.                         IX   = IX   + INCX
  319.                         TEMP = TEMP + AP( K )*X( IX )
  320.   180                CONTINUE
  321.                   ELSE
  322.                      IF( NOUNIT )
  323.      $                  TEMP = TEMP*CONJG( AP( KK ) )
  324.                      DO 190, K = KK + 1, KK + N - J
  325.                         IX   = IX   + INCX
  326.                         TEMP = TEMP + CONJG( AP( K ) )*X( IX )
  327.   190                CONTINUE
  328.                   END IF
  329.                   X( JX ) = TEMP
  330.                   JX      = JX   + INCX
  331.                   KK      = KK   + ( N - J + 1 )
  332.   200          CONTINUE
  333.             END IF
  334.          END IF
  335.       END IF
  336. *
  337.       RETURN
  338. *
  339. *     End of CTPMV .
  340. *
  341.       END
  342.